REM2003jan08-Alain Brobecker (baah/Arm's Tech)
REMon s'arrete des qu'une decomposition est trouvee, et on 'crible'.
max=320
DIMbon(max):FORc=1TOmax:bon(c)=0:NEXT
DIMterme(INT(SQRmax))   :REMtermes de la decomposition
FORn=1TOmax
  IFbon(n)>0THEN
    PRINT;n;"*"
    PROCcrible(n)
  ELSE
    nbtermes=1
    bon=0
    maxnbtermes=INT(SQRn)
    WHILE(bon=0)AND(nbtermes<=maxnbtermes)
      PROCdecompose(1,2,n,1,1)
      nbtermes+=1
    ENDWHILE
    IFbon=1THEN
      bon(n)=1
      PROCcrible(n)
    ENDIF
  ENDIF
NEXTn
END

REMdeclare to les m*n+m*(m-1) comme bons
DEFPROCcrible(n)
LOCALi,m
  m=2
  i=m*(n+m-1)
  WHILEi<=max
    bon(i)=2
    m+=1
    i=m*(n+m-1)
  ENDWHILE
ENDPROC

REMdecomposition recursive
DEFPROCdecompose(position,debut,reste,p,q)
LOCALi,p2,q2,nbrestant
  IFbon=1THENENDPROC
  nbrestant=nbtermes+1-position
  IFnbrestant>1THEN
    i=debut
    WHILE(nbrestant*i<=reste)
      p2=p*i-q
      IFp2>=0THEN
        q2=q*i
        g=FNgcd(p2,q2)
        p2=p2/g
        q2=q2/g
        terme(position)=i
        PROCdecompose(position+1,i,reste-i,p2,q2)
      ENDIF
      i+=1
    ENDWHILE
  ELSE
    IFp*reste=q THEN
      bon=1
      PRINT;n;" = ";
      i=1
      WHILEi<position
        PRINT;terme(i);"+";
        i+=1
      ENDWHILE
      PRINT;reste
    ENDIF
  ENDIF
ENDPROC

DEFFNgcd(a,b)
LOCALc
  IFb<a THEN SWAPa,b :REMb>=a
  WHILEa<>0
    c=b MOD a
    b=a
    a=c
  ENDWHILE
=b